error - contact

  • 2.4K Views
  • Last Post 4 weeks ago
  • Topic Is Solved
daiasena posted this 13 April 2019

Dear all,

I am analyzing a reinforced concrete frame. The connection between the elements is made through a system formed by a screw and steel plate. The connection region is filled with grout, but for initial analysis, I suppress the grout. Taking the advantage of symmetry, I modeled just half of structure.

For the numerical simulation, the following conditions were adopted:

-Element Solid65 for concrete and Link180 for reinforcement.

-The contact between the elements was defined as bonded, with Auto-Asymmetric behavior and Pure Penalty formulation (the only exception is for the region between the load suport and beam, in which the formulation is MPC).The contact tool did not indicate gap or penetration.

- For the mesh, Multizone method was employed and contact sizing option were used to refine the mesh in the contact regions.

- The load was applied  in form of displacements that gradually increase with each load step (20 mm divided in 10 steps). Also, the bolt was pre-tensioned.

After solve, the program shows the following messages for many nodes:

"NOTE:                           

Node 112187 belongs to element 103346.  The CEINTF operation will not consider this node/element combination.                                

WARNING:  SUPPRESSED MESSAGE   

Node 26250 does not lie on or near the selected elements.  The CEINTF operation produced no results for this node. 

The number of ERROR and WARNING messages exceeds 10000.                

Use the /NERR command to increase the number of messages.             

The ANSYS run is terminated by this error. "

 

My questions are:

a) What are the meanings of these warnings and notes? Is it because of contact sizing I insert?

b) I saw these messages in the file0 (.err). I could not open the solver file because it is too big. Is there any way to solve this problem?

c) Is it possible to know the exact position of the nodes and elements that appear in these messages?

Any help and suggestion would be very appreciated.

Thanks is advanced!

 

 

 

Order By: Standard | Newest | Votes
otepman posted this 15 April 2019

Hi daiasena,

Same here. I got the same error after solving. I bet there is something wrong in the constraint equation operation for the line and solid elements. Have you tried the /NERR command? If so, did you get good results?

Someone please help us out here. I have urgent submission for my school works.

Thanks!

daiasena posted this 16 April 2019

Hi, otepman

I´ve tried the NERR command but it did not work.

Does anyone knows what the following warning means? 

 

WARNING:    

Node 26250 does not lie on or near the selected elements.  The CEINTF operation produced no results for this node. 

 Thanks!

Wenlong posted this 16 April 2019

Hi Daiasena,

Could you please try changing the pinball region to "radius" and manually define a contact search radius? It looks to me like the node is not within the vicinity of elements. 

Did you use "contact-bonded-MPC" to bond the reinforcement rebars to concrete as well? Or did you manually inserted a command "CEINTF" to tie them?

Bests,

Wenlong

daiasena posted this 17 April 2019

Thank you very much for your answer!!

To bond the reinforcement rebars (Link180) to concrete (solid65) I manually inserted a CEINTF command:

/PREP7

ESEL,S,ENAME,,65

ESEL,A,ENAME,,180

ALLSEL,BELOW,ELEM

CEINTF,0.001,

ALLSEL,ALL

/SOLU

OUTRES,ALL,ALL

 

I did you suggestion.

Before, the pinball was 2 mm because i  realized that just with values smaller than 2 mm i do not have initial gap and penetration.

I changed to 10 mm, but now i have a inital gap and the warning message is not gone.

 

Wenlong posted this 17 April 2019

Hi Daiasena,

I have not looked into CEINTF command much, but I have tested out REINF command, that works well in generating reinforcements for concrete. That may be a workaround for your situation.

To use REINF, you need these steps:

1. Create base elements (In your case you have SOLID65)

2. Create beam elements (in your case it's LINK180)

3. Use EMODIF to change the beam elements' ename to MESH200

4. Select both MESH200 elements and base elements

5. Use EREINF. It will generate reinforce elements REINF264 that connects your solid element at your previously defined link element location. 

I attached below my command file, in which I use SOLID185 and BEAM188, but I don't think that matters. These commands are inserted in the analysis module. 

 

!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

! Procedure to create reinfocement in concrete:


!   1. create base elements

!   2. create Mesh200 elements. Define proper reinf section for mesh200

!   3. select both base and mesh200 elements

!   4. use ereinf to generate reinforce elements

finish

/prep7




! Define material properties

matid = 1001

mp,ex, matid, 1000

mp,prxy,matid, .3

mp,dens,matid, .0001




! Define a new section id

sectypeid = 1002

secarea   = 10          !mm^2




! Define a new element type id

etype_id  = 1003




! Define a new section and new element type

sectype, sectypeid, reinf, discrete  ! Define a discrete reinf section

secdata, matid, secarea, mesh        ! Define the section properties




! Define a new element type Mesh200

et, etype_id, 200, 2




! Change the Beam188 to Mesh200

esel,s,ename,,188

emodify, all, type, etype_id        ! Define a  

emodify, all, secnum, sectypeid




! Select both the Mesh200 and the base Solid185 element

esel,all




! Generate reinf264 elements. 

EREINF




! Delete the mesh200 elements

esel,s,ename,,mesh200

edele,all

FINISH




! To verify, we can print the the element types

allsel,all

/com,============================================

etlist,all

/com,============================================

/com, =====  Solid elements =========

esel,s, ename,, 185

/com, =====  Beam elements =========

esel,s, ename,,188

/com, =====  Reinforce element =========

esel,s, ename,, 264




allsel,all 




! Go to solution module

/SOLU

!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

 

 

Note that REINF264 elements need to be post-processed using some commands as well. Below are my commands to visualize them in PNG images in Mechanical. I added this command object in the solution module. 

! $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$4

! Graphics power needs to be turned on to view the rebars

/graphics,power




! Enter /post1 module

/post1




! Show result as a png image

/SHOW,png




! Set the frame as the last substep of the 1st step

set,1,last




! Select the SOLID185 elements

esel,s,ename,185

/trlcy,elem,0.5     ! Change them to transparent level 0.5 (0 is solid, 1 is completely transparent)

esel,all




! Set view angle

/view,1,1,1,1

/angle,1,-0.75




! Show the whole section of the reinforcement

/eshape,1 




! Plot displacement

plnsol,u,x 

! $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$4

 

 

And my output looks like this:

 

For more information, you can refer to element type REINF264 and the ANSYS Structural Analysis Guide Chapter 14 "Reinforcing"

 https://ansyshelp.ansys.com/account/secured?returnurl=/Views/Secured/corp/v193/ans_str/Hlp_G_STRRFDEF.html

 

Hope this helps.

Bests,

Wenlong

  • Liked by
  • emanuelandrade
  • Dodo
daiasena posted this 23 April 2019

Hi, wenzhang!

Thank you very much for your suggestion.

Some comments:

1) I tried using the REINF command to create the rebars, but apparently the problem continues, as you can see in the picture:

 

I only changed the first line (matid = 2,relating to Solid 65) and the section area from your command, generating the following result:

2) The solver file shows this warning message:

*** WARNING ***                        

 Material table TB,CONC for material 2 cannot be used with element type  REINF264.  The table will be ignored.           

 

3)  I also followed the recommendation from @peteroznewman. change the beam body into a multibody part to make the element size on the beam and rebar equal. I tried to put the rebar nodes at beams nodes.

https://studentcommunity.ansys.com/thread/transient-structural-analysis-steel-concrete-girder/?order=all#comment-9627f783-e8c2-4193-a208-a9bb00d36488

 

        

 

Any suggestion? 

I do not know if you have permission, but could you take a look at my archive file? Maybe i am doing something very wrong!

 

Thanks!

Wenlong posted this 25 April 2019

The reason is probably that my selection was based on element names so you need to modify one more line. I have BEAM188 elements in my model while you have LINK180 initially. 

In the above lines, you can change 188 to 180, then it will select your link 180 elements and change the elements to MESH200 elements.

Below is a flow chart of the whole procedure:

 

Please try this and see if it helps.

 

Best Regards,

Wenlong

  • Liked by
  • daiasena
  • FlaviaGelatti
Wenlong posted this 10 May 2019

Hi daiasena,

Another way I recently found a way to model the reinforced concrete WITHOUT using a command object or contact. Here are the steps:

1. When creating the geometry (in SpaceClaim), make sure the geometry is sliced in a way that the inner edges are aligned with the rebars (Figure 1)

Figure 1.

2. Move the concrete and rebars into the same component, and change the "Share Topology" to "Merge" (Figure 2)

 

Figure 2

3. Now, these reinforcement rebars will share the same nodes are the concrete and they can deform together (Figure 3). (Some solid elements are hidden to show the deformed shape of rebars)

Figure 3.

 

Hope this helps.

Best Regards,

Wenlong

 

emanuelandrade posted this 23 May 2019

I pretend to analyze a RC beam column joint. I don’t have much knowledge of Ansys. So, how can I model a beam column joint?

Diegoandree1311 posted this 24 September 2019

these are the concrete commands, then steel, and the preprocessing commands respective

!Data Element Type

ET,1,SOLID185

 

 

!Data Material Properties

MP,EX,1,30640

MP,NUXY,1,0.2

 

 

!Data Input Non Metal Plasticity-Concrete

TB,MPLAN,1,1,6

TBDATA,1,0.784,0.784,0.123,5.33e-5,0.7,30

 

!Data Input Stress-Strain Non Linear - Multilinier Kinematic Hardening (Model Kent-Park Unconfined)

TB,KINH,1,1,7

TBPT,DEFI,0.0001,3.064

TBPT,DEFI,0.0005,13.886

TBPT,DEFI,0.001,24.194

TBPT,DEFI,0.0015,30.922

TBPT,DEFI,0.002,34.072

TBPT,DEFI,0.00219,34.33

TBPT,DEFI,0.003,29.181

 

This is the link180 reinforcing steel

ET,3,LINK180

 

MP,EX,3,199947.96

MP,NUXY,3,0.3

 

TB,BISO,3,1,2

TBDATA,1,414,50000

SECTYPE,3,LINK,ELASTIC,BARRAinf,0,

SECDATA,286.51

ELIST,,,,,1

/ESHAPE

preprocessing commands

/PREP7

ESEL,S,ENAME,,185

ESEL,A,ENAME,,180

ALLSEL,BELOW,ELEM

CPINTF,ALL,0.00001,

ALLSEL,ALL

/SOLU

OUTRES,ALL,ALL

 

 

I am interested in learning to use more commands that help me with this purpose, as is the case of the REINF mentioned by colleague Wenlong, but I don't know how to put it into my programming

I really want to learn to use Ansys but it is a world, and as the thesis I have to deliver it in 4 months, I have no time to lose, thank you very much to all who can help me beforehand, greetings

 

Wenlong posted this 24 September 2019

Hi,

This link has all the documentation of commands and will be very helpful: https://ansyshelp.ansys.com/account/secured?returnurl=/Views/Secured/corp/v194/ans_cmd/Hlp_C_CmdTOC.html 

 

You can also refer to this link, it has many examples about APDL commands:https://ansyshelp.ansys.com/account/secured?returnurl=/Views/Secured/corp/v193/ans_tec/tecintro.html

Bests,

Wenlong

 

 

  • Liked by
  • Diegoandree1311
Diegoandree1311 posted this 27 September 2019

 

I have problems entering the Ansys help because it tells me that my account does not exist, is there any other page where I can find examples? I am reading the following documents to guide me

 

I will take this opportunity to have a question

 

 

what I understand is that there are 2 ways to create contacts, with REINF or with CPINTF and I am currently using CPINTF but the contact is not created, before if I did it between solid65 and link180 (it worked perfect), but now as it changes me at solid185 the contact is giving me problems and I don't know if I am getting any bad data or that CPINTF command is only for the soli65 element, or it can also be the definition of the constant parameters, because I am not using the command R or Rmore, I'm using: Sectype and Secdata, because I don't know how to use the R command

 

Could you help me understand what values are entered and in what order in the R command? is that the documents I have do not define it for a steel bar.

 

regards

 

 

 

Diegoandree1311 posted this 27 September 2019

Checking in different places and I came up with the answer, Link180 no longer supports the R (realconstant) command. The SECTYPE, and SECDATA commands are currently being used

vaibhavtaranekar posted this 10 October 2019

Checking in different places and I came up with the answer, Link180 no longer supports the R (realconstant) command. The SECTYPE, and SECDATA commands are currently being used

 

Can you post the new ADPL commands for link 180 ? i need reference for my work.

 

 

peteroznewman posted this 10 October 2019

How to open ANSYS Help links provided in these posts using a Student license.

Here is an example where SECTYPE and SECDATA were used.

Lagin posted this 21 October 2019

Hello all,
I´d like to please you for help.

In my thesis, I have concrete U shape component reinforcered by steel, where we study behaviour of the corner while opening.


Concrete is defined by library as nonlinear with softening. 

concrete - library

+ in command: 

ET,MATID,SOLID65

to define solid as solid65

Reinforcement by command (from DrDalyO videos):

ET,MATID,LINK180

MPDATA,EX,MATID,,2e5

MPDATA,PRXY,MATID,,0.3

TB,BISO,MATID,1,2

TBDATA,,460,2100

 

R,MATID,12,,0

Next I tried to define contact (from DrDalyO videos):

 

/PREP7

ESEL,S,ENAME,,65

ESEL,A,ENAME,,180

ALLSEL,BELOW,ELEM

CEINTF,0.001,

ALLSEL,ALL

/SOLU

OUTRES,ALL,ALL

- contact works (rc deform with concrete component), but program shows many note like: 
Node XXX belongs to element XXX.  The CEINTF operation will not consider this node/element combination.

and I´m not sure, if it´s acceptable?  

So next I tried to use commands written by @Wenlongand and change few lines.

finish

 

/prep7

 

 

 

 

! Define material properties

 

matid = 10001

 

mp,ex, matid,31400

 

mp,prxy,matid,0.2

 

mp,dens,matid,0.24e-5

 

 

 

 

! Define a new section id

 

sectypeid = 10002

 

secarea   = 20          !mm^2

 

 

 

 

! Define a new element type id

 

etype_id  = 10003

 

 

 

 

! Define a new section and new element type

 

sectype, sectypeid, reinf, discrete  ! Define a discrete reinf section

 

secdata, matid, secarea, mesh        ! Define the section properties

 

 

 

 

! Define a new element type Mesh200

 

et, etype_id, 200, 2

 

 

 

 

! Change the Link180 to Mesh200

 

esel,s,ename,,180

 

emodify, all, type, etype_id        ! Define a  

 

emodify, all, secnum, sectypeid

 

 

 

 

! Select both the Mesh200 and the base Solid65 element

 

esel,all

 

 

 

 

! Generate reinf264 elements. 

 

EREINF

 

 

 

 

! Delete the mesh200 elements

 

esel,s,ename,,mesh200

 

edele,all

 

FINISH

 

 

 

 

! To verify, we can print the the element types

 

allsel,all

 

/com,============================================

 

etlist,all

 

/com,============================================

 

/com, =====  Solid elements =========

 

esel,s, ename,, 65

 

/com, =====  Link elements =========

 

esel,s, ename,,180

 

/com, =====  Reinforce element =========

 

esel,s, ename,, 264

 

 

 

 

allsel,all 

 

 

 

 

! Go to solution module

 

/SOLU

This contact doesn´t work in my model.

Third option, slice component and merge components in SpaceClaim is I think impractical because I have too many elements and model is blinded then.

Please help me, I´m suffering with model for more than two months and you are me last hope.
Thank you for any advice.

CivilIsrael posted this 02 May 2020

What does this mean ?????

 

 

Hi daiasena,

Another way I recently found a way to model the reinforced concrete WITHOUT using a command object or contact. Here are the steps:

1. When creating the geometry (in SpaceClaim), make sure the geometry is sliced in a way that the inner edges are aligned with the rebars (Figure 1)

Figure 1.

2. Move the concrete and rebars into the same component, and change the "Share Topology" to "Merge" (Figure 2)

 

Figure 2

3. Now, these reinforcement rebars will share the same nodes are the concrete and they can deform together (Figure 3). (Some solid elements are hidden to show the deformed shape of rebars)

Figure 3.

 

Hope this helps.

Best Regards,

Wenlong

 

  • Liked by
  • Vimalnathrao
Wenlong posted this 04 May 2020

Hi,

It is to model the solid and beams (rebars) in a way that they have merged geometries, so when you mesh them, they will have common nodes, and no command object is needed. 

Please let me know which part you don't understand. Thanks.

Regards,

Wenlong

 

CivilIsrael posted this 14 May 2020

Hello Wenlong

The inner edges are sliced at the rebar?

Regards,

Israel

Wenlong posted this 14 May 2020

Hi Israel,

Yes, at both the rebars and the stir-ups.

Regards,

Wenlong

 

  • Liked by
  • CivilIsrael
Bukky1 posted this 4 weeks ago

I tried this with my model but after refreshing, it becomes invisible in workbench

Close